Создание базовой игры

Чтобы помочь вам начать, это руководство проведёт вас через создание игры по сбору яблок!

Коллекция яблок

В этом примере игра лишь поверхностно затрагивает детали, которые подробно рассматриваются в других руководствах. Если вам нужна помощь, проверьте левую боковую панель или воспользуйтесь поиском вверху для дополнительной информации!

Создание карты

Начнём с создания простого мира с островом, по которому можно ходить, и яблоком, которое можно будет собрать позже!

1. Найдите Apple и Island в Каталог ресурсов и перетащите их в сцену вашей игры.

1. Этот остров довольно маленький! В Инспектор установите Scale в 10x10, чтобы сделать его больше

1. Теперь остров подходящего размера, но яблоко находится за островом! Установите у острова Layer на -10, чтобы поместить его позади всего остального.

Добавление скриптов

В каталоге scripts вашего проекта игры создайте новый файл с именем pickup_apple.csl и откройте его в текстовом редакторе или используйте IDE на основе ИИ.

Вставьте следующий пример скрипта и сохраните файл:

// Это создаёт компонент, делающий яблоко взаимодействуемым,
// мы добавим его к Apple на следующем шаге руководства. 
Pickup_Apple :: class : Interactable {
    is_picked_up: bool;

    ao_start :: method() {
        this->set_listener(this);
        this->set_text("Подобрать");
    }

    can_use :: method(player: Player) -> bool {
        if is_picked_up return false;
        return true;
    }

    on_interact :: method(player: Player) {
        if is_picked_up return;
        is_picked_up = true;

        // Запустить эффект появления
        effect := new(Apple_Pop_Effect);
        entity->set_active_effect(effect);
    }
}

// Классная анимация на случай, когда вы его съедаете :D 
Apple_Pop_Effect :: class : Effect_Base {
    sprite: Sprite_Renderer;
    start_scale: v2;
    start_pos: v2;

    effect_start :: method() {
        sprite = entity->get_component(Sprite_Renderer);
        start_scale = entity.local_scale;
        start_pos = entity.local_position;
        set_duration(0.4);
    }

    effect_update :: method(dt: float) {
        t := get_elapsed_time() / 0.4;

        // Увеличить, а затем быстро уменьшить до нуля
        scale_curve: float;
        if t < 0.3 {
            // Быстрое появление (масштаб до 1.3x)
            scale_curve = lerp(1.0, 1.3, Ease.out_back(t / 0.3));
        } else {
            // Уменьшить до нуля
            scale_curve = lerp(1.3, 0.0, Ease.in_back((t - 0.3) / 0.7));
        }

        entity->set_local_scale(start_scale * scale_curve);

        // Немного подняться вверх
        rise := Ease.out_quad(t) * 0.5;
        entity->set_local_position({start_pos.x, start_pos.y + rise});

        // Исчезнуть ближе к концу
        if sprite != null {
            alpha := 1.0 - Ease.in_quad(max(0.0, (t - 0.5) / 0.5));
            sprite.color.w = alpha;
        }
    }

    effect_end :: method(interrupt: bool) {
        entity->destroy();
    }
}

Предупреждение: После сохранения вашего компонента в текстовом редакторе вам нужно обновить движок, нажав Ctrl + Shift + R. Это временное требование, и скоро будет доступна горячая загрузка!

Добавление компонента Apple

Теперь, когда вы создали скрипт для яблока, нам нужно применить его к яблоку в сцене. Для этого мы добавим новый Pickup_Apple компонент из скрипта, используя Inspector.

1. Выберите своё Apple в сцене

2. Нажмите кнопку "Add Component" в Inspector.

3. Найдите компонент "Pickup_Apple" и нажмите на него, чтобы добавить его к яблоку

Теперь вы увидите, что компонент был добавлен к яблоку! Вы можете настроить некоторые поля у Apple, изменяя значения в Inspector:

Запуск вашей игры

Когда будете готовы, нажмите на зелёный треугольник и попробуйте свою игру!

Следующие шаги

В следующих разделах вы узнаете, как проводить плейтест своей игры с несколькими игроками, создавать собственные скрипты и строить мир своей мечты.

Вот несколько задач, которые можно попробовать:

• Сделайте много яблок, которые игрок сможет съесть

• Воспроизводите звуковые эффекты при съедании

• Продвинутый уровень: попробуйте написать скрипт, который будет заново создавать больше яблок после того, как их съедят

--

ПРИМЕЧАНИЕ: Если ваш остров имеет низкое разрешение/пикселизирован, нажмите на png-ресурс острова в разделе "Assets" и установите Resample Multiplier на 1, затем нажмите Apply