Социальные функции

All Out предоставляет текстовый и, при желании, голосовой чат, который можно использовать в играх

Чтение чата

Используйте core_globals.server_on_chat_message_received когда игровой код должен реагировать на обычные сообщения чата на сервере:

ao_before_scene_load :: proc() {
    core_globals.server_on_chat_message_received = on_chat_message;
}

on_chat_message :: proc(player: Player, message: string) {
    log_info("% сказал %", {player.get_username(), message});
}

Справочник API чата

Chat :: struct {
    Mode :: enum {
        DEFAULT;
        BUBBLE_ONLY;
    }

    set_mode :: proc(mode: Mode);
    server_send_message :: proc(message: string, player: Player = null);
    is_open :: proc() -> bool;
}

Chat.server_send_message предназначен для серверного кода, такого как обработчики команд чата. Передайте игрока чтобы нацелить на одного игрока, или оставьте null пустым, чтобы отправить всем. Используйте Chat.set_mode(.BUBBLE_ONLY) на локальном клиенте для игр, которым нужен пузырьковый чат без стандартной панели чата.

Команды чата

Команды чата — это в основном инструмент для разработчиков/админов для тестирования и live-ops:

• Запускать раунды раньше / пропускать волны
• Выдавать тестовые наборы предметов или валюту
• Вызывать игровые события для отладки

Чтобы создать команду, напишите proc и пометьте её с помощью @chat_command.

Игроки могут вводить команды в чат, начиная с /:

• /start_round
• /grant_test_loadout
• /trigger_event meteor_shower

Команды чата выполняются на сервере. Используйте Notifier.notify(player, "...") чтобы отправлять обратную связь одному игроку.

У не всех игроков включён текстовый чат (родительский контроль и заглушения модерации могут отключать текстовое поле), поэтому не следует полагаться на команды чата для критически важных игровых систем.

Распространённые команды для разработчиков/админов

// Запустить раунд раньше (только для админов)
start_round :: proc(player: Player) {
    g_round_manager.start_round();
    Notifier.notify(player, "Раунд начат.");
} @chat_command

// Выдать себе тестовый набор (только для админов)
grant_test_loadout :: proc(player: Player) {
    // Пример: используйте здесь свою собственную логику выдачи предметов
    // item := Items.create_item_instance(sword_defn);
    // Items.move_item_to_inventory(item, player.default_inventory);
    Notifier.notify(player, "Выдан тестовый набор.");
} @chat_command

// Вызвать событие по имени (только для админов, с необязательным аргументом)
trigger_event :: proc(player: Player, event_name: string = "meteor_shower") {
    g_event_system.trigger(event_name);
    Notifier.notify(player, "Событие вызвано: %", {event_name});
} @chat_command

Права доступа

Используйте аннотации прав доступа, чтобы контролировать, кто может запускать команду:

Аннотация	Кто может использовать
@any	Все игроки
@vip	VIP-игроки и админы
@youtuber	Игроки-ютуберы и админы
@owner	Владелец игры и админы
@owner_or_editor	Владелец игры, редакторы и админы
(нет)	Только админы

// Этим могут пользоваться VIP и админы
skip_wave :: proc(player: Player) {
    g_wave_manager.skip_to_next_wave();
    Notifier.notify(player, "Волна пропущена.");
} @chat_command @vip

При запуске из редактора команды чата разрешены для более быстрой итерации/тестирования.

Аргументы и необязательные параметры

Первый параметр всегда должен быть Player. После этого вы можете добавлять аргументы (и задавать им значения по умолчанию, чтобы сделать их необязательными).

По умолчанию команды только для админов.

Поддерживаемые типы аргументов: string, целочисленные типы, типы с плавающей точкой, bool, а Player.

// Только для админов (по умолчанию)
give_currency :: proc(player: Player, amount: s64 = 100) {
    if amount < 0 {
        Notifier.notify(player, "Сумма должна быть не меньше нуля.");
        return;
    }

    Economy.deposit_currency(player, "Coins", amount);
    Notifier.notify(player, "Выдал вам % монет.", {amount});
} @chat_command

Админы могут вызвать:

• /give_currency → даёт 100 монет
• /give_currency 500 → даёт 500 монет

Строки с пробелами

Заключайте строки в кавычки, если они содержат пробелы:

say :: proc(player: Player, message: string) {
    // Ваша собственная функция вещания/игровое сообщение здесь
    log_info("% говорит: %", {player.get_username(), message});
} @chat_command @any

Пример:

/say "Привет всем!"

Получение использования команды

Игроки могут добавить ? к команде, чтобы увидеть информацию о параметрах:

/spawn_enemy?

Включение голосового чата

Игроки управляют голосовым чатом через настройки своей учётной записи и устройства. Игры не могут принудительно включить его или обойти разрешение на микрофон, родительский контроль или ограничения модерации.

Голосовой чат привязан к позиции. Стандартный радиус слышимости — 10 единиц мира:

Voice :: struct {
    set_range :: proc(range: float);
    get_range :: proc() -> float;
}

Установите положительный радиус во время запуска сцены:

ao_start :: proc() {
    Voice.set_range(14);
}

Voice.set_range изменяет радиус для всей сцены. Неположительные значения игнорируются.

Каналы связи

У каждого игрока есть маски передачи и прослушивания, которые применяются и к голосовому, и к текстовому чату. Два игрока могут общаться, когда маска передачи отправителя пересекается с маской прослушивания получателя.

TEAM_RED  :: 1.(u64) << 0;
TEAM_BLUE :: 1.(u64) << 1;

put_on_red_team :: proc(player: Player) {
    player.comms_channel_speak_mask = TEAM_RED;
    player.comms_channel_listen_mask = TEAM_RED;
}

По умолчанию игроки слушают и говорят на всех каналах.

Модерация

All Out автоматически отслеживает текстовый и голосовой чат на предмет поведения, нарушающего наши правила сообщества и отключит социальные функции за первое нарушение или применит блокировки за повторные нарушения.

Если вы видите повторяющееся плохое поведение или поведение, которое прошло мимо нашего автоматического обнаружения, пожалуйста, сообщите нам об игроке через внутриигровую систему жалоб или из его профиля.

Если игрок был ошибочно заблокирован, пожалуйста, направьте его к свяжитесь с нами чтобы отменить это действие.