Интерактивные объекты

Компонент Interactable

Добавление компонента Interactable к сущности автоматически будет показывать UI, когда игроки находятся в пределах радиуса который вы зададите.

Радиус взаимодействия масштабируется вместе с мировым масштабом сущности, поэтому держите корень interactable в масштабе 1 и масштабируйте визуальный дочерний объект, если хотите, чтобы дальность взаимодействия оставалась фиксированной.

Чтобы реагировать на нажатие игроком на interactable, вам нужно написать код CSL.

У сущности может быть больше одного Interactable. Используйте приоритет когда несколько подсказок могут быть доступны одновременно.

Самый распространённый шаблон такой:

• Создайте класс, который наследуется от Interactable
• Вызывайте this.set_listener(this) в ao_start
• Реализуйте can_use и on_interact в вашем классе

Если вы добавляете новый класс interactable в коде, вам всё равно нужно добавить этот компонент к сущности в редакторе (или создать сущность и добавить компонент во время выполнения).

Пример с мусором

// Получайте монеты за подбор мусора :D
Trash :: class : Interactable {
    coins: s64 @ao_serialize;
    used: bool;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("Подобрать мусор");
        this.set_hold_text("Подбираю...");
        required_hold_time = 0.25;
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        if used return false;
        return true;
    }

    on_interact :: method(player: Player) {
        used = true;
        Economy.deposit_currency(player, "Coins", coins);
        entity.destroy();
    }
}

Пример роста

Interactable, который «увеличивает» сущность (один раз):

Grow_Button :: class : Interactable {
    scale_multiplier: float @ao_serialize;
    used: bool;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("Увеличить");
        radius = 1.25;
        required_hold_time = 0;
    }

    can_use :: method(player: Player) -> bool {
        return !used;
    }

    on_interact :: method(player: Player) {
        used = true;
        new_scale := entity.local_scale * scale_multiplier;
        entity.set_local_scale(new_scale);
        this.set_text("Уже использовано");
    }
}

Пример с запросом на покупку

Interactable, который открывает окно покупки товара:

Buy_Admin_Pass :: class : Interactable {
    product_id: string @ao_serialize;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("Купить админ-доступ");
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        // Пример проверки: скрыть, если уже куплено (game pass)
        return !Purchasing.owns_product(player, product_id);
    }

    on_interact :: method(player: Player) {
        Purchasing.prompt_purchase(player, product_id);
    }
}

Справочник API

Interactable :: class : Component {
    // Текст подсказки (взаимодействие по нажатию)
    get_text :: method() -> string;
    set_text :: method(text: string);

    // Текст подсказки при удержании (для взаимодействия с удержанием)
    get_hold_text :: method() -> string;
    set_hold_text :: method(text: string);

    get_subtitle :: method() -> string;
    set_subtitle :: method(text: string);

    // Подключает объект-слушатель, который реализует:
    // - can_use(player: Player) -> bool
    // - on_interact(player: Player)
    // - on_holding(player: Player) [необязательно]
    set_listener :: method(new_listener: Component);

    // Общие поля (задаются в редакторе или в коде)
    offset: v2;
    prompt_offset: v2;
    radius: float;
    required_hold_time: float;
    priority: s64;
    subtitle_color: v4;
}

Необязательные хуки игрока (глобальные правила)

Вы также можете реализовать это в вашем Player классе, чтобы задать правила для всей игры (например, нельзя использовать interactables до возрождения):

Player :: class : Player_Base {
    ao_can_use_interactable :: method(interactable: Interactable) -> bool {
        return true;
    }

    ao_on_interactable_used :: method(interactable: Interactable) {
    }

    ao_on_holding_interactable :: method(interactable: Interactable) {
    }
}