Inventory

Обзор

All Out предоставляет API инвентаря игрока, которое позволяет создавать предметы, выдавать их игрокам, а также позволяет игрокам размещать, использовать и выбрасывать предметы в вашей игре.

Есть три основных понятия:

• Определения предметов (Item_Definition): что такое предмет является (название/иконка/стекование + ваши собственные поля)

• Экземпляры предметов (Item_Instance): фактический стек в мире/в инвентаре

• Инвентари (Inventory): контейнер слотов, который хранит экземпляры предметов

У каждого игрока есть встроенный инвентарь в player.default_inventory.

Сохранение

Если вы хотите, чтобы инвентари игроков автоматически сохранялись между игровыми сессиями, включите флажок "Auto Save Player Inventory" в разделе Edit -> Game Settings в редакторе

Справочник API инвентаря

Item_Definition_Desc :: struct {
    id:         string;
    name:       string;
    icon:       Texture_Asset;
    stack_size: s64;    // 1 = не стакается, -1 = бесконечно
    tier:       Item_Tier;
}

Items :: struct {
    // Инвентари
    create_inventory  :: proc(unique_id: string, capacity: s64) -> Inventory;
    destroy_inventory :: proc(inventory: Inventory) -> bool;
    set_capacity      :: proc(inventory: Inventory, capacity: s64);

    // Определения предметов + экземпляры
    register_item_definition :: proc(desc: Item_Definition_Desc, $Definition_Type: typeid = Item_Definition, instance_type: typeid = Item_Instance) -> Definition_Type;
    create_item_instance     :: proc(definition: Item_Definition, count: s64 = 1) -> Item_Instance;
    create_item_instance     :: proc(definition: Item_Definition, $T: typeid, count: s64 = 1) -> T;
    destroy_item_instance    :: proc(instance: Item_Instance, count: s64 = -1);

    // Перемещение предметов
    can_move_item_to_inventory                  :: proc(instance: Item_Instance, inventory: Inventory, will_destroy_item: ref bool) -> bool;
    move_item_to_inventory                      :: proc(instance: Item_Instance, inventory: Inventory);
    move_as_many_items_as_possible_to_inventory :: proc(instance: Item_Instance, inventory: Inventory, destroyed_item: ref bool) -> s64;
    remove_item_from_inventory                  :: proc(instance: Item_Instance, inventory: Inventory);
    can_swap_items                              :: proc(inventory_a: Inventory, inventory_b: Inventory, slot_a: s64, slot_b: s64) -> bool;
    swap_items                                  :: proc(inventory_a: Inventory, inventory_b: Inventory, slot_a: s64, slot_b: s64);

    // Запросы
    calculate_room_in_inventory_for_item :: proc(definition: Item_Definition, inventory: Inventory) -> s64;
    destroy_all_items :: proc(inventory: Inventory);

    // UI (необязательно)
    draw_inventory :: proc(rect: Rect, inventory: Inventory, options: Inventory_Draw_Options) -> bool;
    draw_hotbar    :: proc(player: Player, inventory: Inventory, options: Inventory_Draw_Options) -> Draw_Hotbar_Result;
}

Inventory :: class : Inventory_Base {
    get_item :: proc(inventory: Inventory, index: s64) -> Item_Instance;
}

Item_Definition :: class : Item_Definition_Base {
    get_name :: method() -> string;
    get_id   :: method() -> string;
    get_icon :: method() -> Texture_Asset;
}

Item_Instance :: class : Item_Instance_Base {
    get_definition :: method() -> Item_Definition;
}

Быстрый старт (зарегистрировать + выдать предмет)

Зарегистрируйте определения предметов один раз в ao_before_scene_load, затем создавайте экземпляры и перемещайте их в инвентарь игрока.

// Необязательно: пользовательские типы предметов
Weapon_Definition :: class : Item_Definition {
    damage: s64;
}

Weapon_Item :: class : Item_Instance {
    durability: s64 @ao_serialize; // @ao_serialize заставляет это поле автоматически сохраняться между сессиями
}

sword_defn: Weapon_Definition;

ao_before_scene_load :: proc() {
    sword_defn = Items.register_item_definition(
        {id="sword", name="Iron Sword", icon=get_asset(Texture_Asset, "icons/sword.png"), stack_size=1, tier=.COMMON},
        Weapon_Definition,
        Weapon_Item
    );
    sword_defn.damage = 10;
}

give_sword :: proc(player: Player) {
    item := Items.create_item_instance(sword_defn, Weapon_Item);

    will_destroy: bool;
    if Items.can_move_item_to_inventory(item, player.default_inventory, ref will_destroy) {
        item.durability = 100;
        Items.move_item_to_inventory(item, player.default_inventory);
    }
    else {
        // Инвентарь полон → уничтожить созданный нами экземпляр
        Items.destroy_item_instance(item);
    }
}

Отображение хотбара

Чтобы показать на экране стандартный UI хотбара инвентаря, вызовите Items.draw_hotbar внутри метода ao_late_update вашего Player. Без этого система инвентаря будет работать в фоне, но игрок её не увидит!

Player :: class : Player_Base {
    ao_late_update :: method(dt: float) {
        if this->is_local_or_server() {
            draw_player_hotbar(this);
        }
    }
}

draw_player_hotbar :: proc(player: Player) {
    options := Inventory_Draw_Options.default();
    result := Items.draw_hotbar(player, player.default_inventory, options);

    // result.selected_item — это текущий выделенный предмет (или null)
    // result.inventory_open сообщает, открыт ли полный UI сумки
}

Items.draw_hotbar обрабатывает за вас весь UI хотбара + переключение сумки. Он возвращает Draw_Hotbar_Result с selected_item, selected_item_index, inventory_open, и dropped_item полями.

Проверка, есть ли у игрока уже предмет

Распространённый шаблон — выдавать предмет только если у игрока ещё нет такого предмета:

player_has_item :: proc(player: Player, definition: Item_Definition) -> bool {
    inv := player.default_inventory;
    for i: 0..inv.capacity-1 {
        item := inv->get_item(i);
        if item != null && item->get_definition() == definition {
            return true;
        }
    }
    return false;
}

give_sword_if_needed :: proc(player: Player) {
    if player_has_item(player, sword_defn) return;
    give_sword(player);
}

Вы также можете проверить, сколько места осталось для конкретного типа предмета, прежде чем создавать его:

room := Items.calculate_room_in_inventory_for_item(sword_defn, player.default_inventory);
if room > 0 {
    give_sword(player);
}

Пользовательские инвентари

Вы можете создавать инвентари, не привязанные к игроку, например для:

• Сундуков / контейнеров для хранения

• Команд рыб/мобов

chest_inventory := Items.create_inventory("chest_01", 12);

Чтобы получить доступ к предметам:

for i: 0..chest_inventory.capacity-1 {
    item := chest_inventory->get_item(i);
    if item == null continue;
    defn := item->get_definition();
    log_info("Slot %: %", {i, defn->get_name()});
}

Выброшенные предметы

Если вы хотите, чтобы игроки выбрасывали предметы в мир (а другие игроки могли их подбирать), используйте систему выброшенных предметов:

import "core:dropped_items"

Создание выброшенного предмета

item := Items.create_item_instance(sword_defn, Weapon_Item);
dropped := Dropped_Item.spawn(player.entity.world_position, item);

Анимация выброса + привязка к navmesh

server_rng: u64;

dropped->do_spawn_animation(ref server_rng, navmesh); // navmesh необязателен

Обработка перетаскивания из UI хотбара

Если вы используете Items.draw_hotbar, игроки могут перетащить предмет из UI, чтобы выбросить его. Dropped_Item.handle_dropped_item удаляет его из инвентаря и создаёт сущность выброшенного предмета.

result := Items.draw_hotbar(player, player.default_inventory, Inventory_Draw_Options.default());

dropped: Dropped_Item;
if Dropped_Item.handle_dropped_item(result, player.entity.world_position, ref dropped) {
    dropped->do_spawn_animation(ref server_rng, navmesh);
}

Выброшенные предметы автоматически исчезают со временем (с предупреждающей полосой). Если удерживать кнопку взаимодействия над предметом, таймер его исчезновения сбрасывается.

Вы можете сделать выброшенный предмет эксклюзивным (видимым/подбираемым только одним игроком) с помощью dropped->set_exclusive(player).