Inventory

概述

All Out 提供了一个玩家库存 API，允许你创建物品、将它们给予玩家，并让玩家在游戏中整理、使用和丢弃物品。

有三个核心概念：

• 物品定义 (Item_Definition）：某个物品的 是 （名称/图标/堆叠 + 你自己的字段）

• 物品实例 (Item_Instance）：世界中/库存中的实际堆叠

• 库存 (Inventory）：一个包含物品实例的槽位容器

每个玩家都有一个内置库存，位于 player.default_inventory.

持久化

如果你希望玩家库存在跨游戏会话时自动保存，请在编辑器的 Edit -> Game Settings 部分勾选“Auto Save Player Inventory”选项。

库存 API 参考

Item_Definition_Desc :: struct {
    id:         string;
    name:       string;
    icon:       Texture_Asset;
    stack_size: s64;    // 1 = 不可堆叠，-1 = 无限
    tier:       Item_Tier;
}

Items :: struct {
    // 库存
    create_inventory  :: proc(unique_id: string, capacity: s64) -> Inventory;
    destroy_inventory :: proc(inventory: Inventory) -> bool;
    set_capacity      :: proc(inventory: Inventory, capacity: s64);

    // 物品定义 + 实例
    register_item_definition :: proc(desc: Item_Definition_Desc, $Definition_Type: typeid = Item_Definition, instance_type: typeid = Item_Instance) -> Definition_Type;
    create_item_instance     :: proc(definition: Item_Definition, count: s64 = 1) -> Item_Instance;
    create_item_instance     :: proc(definition: Item_Definition, $T: typeid, count: s64 = 1) -> T;
    destroy_item_instance    :: proc(instance: Item_Instance, count: s64 = -1);

    // 移动物品
    can_move_item_to_inventory                  :: proc(instance: Item_Instance, inventory: Inventory, will_destroy_item: ref bool) -> bool;
    move_item_to_inventory                      :: proc(instance: Item_Instance, inventory: Inventory);
    move_as_many_items_as_possible_to_inventory :: proc(instance: Item_Instance, inventory: Inventory, destroyed_item: ref bool) -> s64;
    remove_item_from_inventory                  :: proc(instance: Item_Instance, inventory: Inventory);
    can_swap_items                              :: proc(inventory_a: Inventory, inventory_b: Inventory, slot_a: s64, slot_b: s64) -> bool;
    swap_items                                  :: proc(inventory_a: Inventory, inventory_b: Inventory, slot_a: s64, slot_b: s64);

    // 查询
    calculate_room_in_inventory_for_item :: proc(definition: Item_Definition, inventory: Inventory) -> s64;
    destroy_all_items :: proc(inventory: Inventory);

    // UI（可选）
    draw_inventory :: proc(rect: Rect, inventory: Inventory, options: Inventory_Draw_Options) -> bool;
    draw_hotbar    :: proc(player: Player, inventory: Inventory, options: Inventory_Draw_Options) -> Draw_Hotbar_Result;
}

Inventory :: class : Inventory_Base {
    get_item :: proc(inventory: Inventory, index: s64) -> Item_Instance;
}

Item_Definition :: class : Item_Definition_Base {
    get_name :: method() -> string;
    get_id   :: method() -> string;
    get_icon :: method() -> Texture_Asset;
}

Item_Instance :: class : Item_Instance_Base {
    get_definition :: method() -> Item_Definition;
}

快速开始（注册 + 给予物品）

在 ao_before_scene_load中只注册一次物品定义，然后创建实例并将它们移动到玩家的库存中。

// 可选：自定义物品类型
Weapon_Definition :: class : Item_Definition {
    damage: s64;
}

Weapon_Item :: class : Item_Instance {
    durability: s64 @ao_serialize; // @ao_serialize 会让该字段在会话间自动保存
}

sword_defn: Weapon_Definition;

ao_before_scene_load :: proc() {
    sword_defn = Items.register_item_definition(
        {id="sword", name="Iron Sword", icon=get_asset(Texture_Asset, "icons/sword.png"), stack_size=1, tier=.COMMON},
        Weapon_Definition,
        Weapon_Item
    );
    sword_defn.damage = 10;
}

give_sword :: proc(player: Player) {
    item := Items.create_item_instance(sword_defn, Weapon_Item);

    will_destroy: bool;
    if Items.can_move_item_to_inventory(item, player.default_inventory, ref will_destroy) {
        item.durability = 100;
        Items.move_item_to_inventory(item, player.default_inventory);
    }
    else {
        // 库存已满 → 销毁我们创建的实例
        Items.destroy_item_instance(item);
    }
}

显示热键栏

要在屏幕上显示标准库存热键栏 UI，请在玩家的 Items.draw_hotbar 方法内部调用 ao_late_update 。如果不这样做，库存系统仍会在后台运行，但玩家看不到它！

Player :: class : Player_Base {
    ao_late_update :: method(dt: float) {
        if this->is_local_or_server() {
            draw_player_hotbar(this);
        }
    }
}

draw_player_hotbar :: proc(player: Player) {
    options := Inventory_Draw_Options.default();
    result := Items.draw_hotbar(player, player.default_inventory, options);

    // result.selected_item 是当前高亮的物品（或 null）
    // result.inventory_open 表示完整背包 UI 是否正在显示
}

Items.draw_hotbar 会为你处理整个热键栏 + 背包切换 UI。它返回一个 Draw_Hotbar_Result ，其中包含 selected_item, selected_item_index, inventory_open和 dropped_item 字段。

检查玩家是否已经拥有某个物品

常见模式是：只有当玩家还没有该物品时才给予它：

player_has_item :: proc(player: Player, definition: Item_Definition) -> bool {
    inv := player.default_inventory;
    for i: 0..inv.capacity-1 {
        item := inv->get_item(i);
        if item != null && item->get_definition() == definition {
            return true;
        }
    }
    return false;
}

give_sword_if_needed :: proc(player: Player) {
    if player_has_item(player, sword_defn) return;
    give_sword(player);
}

你也可以在创建之前检查某种特定物品类型还剩多少空间：

room := Items.calculate_room_in_inventory_for_item(sword_defn, player.default_inventory);
if room > 0 {
    give_sword(player);
}

自定义库存

你可以创建不绑定到玩家的库存，例如用于：

• 箱子 / 存储容器

• 鱼/怪物队伍

chest_inventory := Items.create_inventory("chest_01", 12);

访问物品：

for i: 0..chest_inventory.capacity-1 {
    item := chest_inventory->get_item(i);
    if item == null continue;
    defn := item->get_definition();
    log_info("槽位 %: %", {i, defn->get_name()});
}

掉落物品

如果你想让玩家把物品丢到世界中（并让其他玩家拾取），请使用掉落物品系统：

import "core:dropped_items"

生成一个掉落物品

item := Items.create_item_instance(sword_defn, Weapon_Item);
dropped := Dropped_Item.spawn(player.entity.world_position, item);

掉落动画 + 吸附到导航网格

server_rng: u64;

dropped->do_spawn_animation(ref server_rng, navmesh); // navmesh 可选

处理来自热键栏 UI 的拖放

如果你使用 Items.draw_hotbar，玩家可以将物品从 UI 中拖出以丢弃它。 Dropped_Item.handle_dropped_item 会将其从库存中移除，并生成一个掉落物品实体。

result := Items.draw_hotbar(player, player.default_inventory, Inventory_Draw_Options.default());

dropped: Dropped_Item;
if Dropped_Item.handle_dropped_item(result, player.entity.world_position, ref dropped) {
    dropped->do_spawn_animation(ref server_rng, navmesh);
}

掉落物品会随时间自动消失（并带有警告条）。按住物品上的交互按钮会重置其消失计时器。

你可以使用 dropped->set_exclusive(player).