可交互对象

Interactable 组件

向实体添加 Interactable 组件后，当玩家位于你指定的 半径 内时。

交互半径会随实体的世界缩放而缩放，因此请将 interactable 根节点保持在 1 倍缩放，并在希望交互范围保持固定时缩放可视子节点。

要响应玩家按下交互物，你需要编写 CSL 代码。

一个实体可以拥有多个 Interactable。使用 优先级 ，当多个提示可能同时可用时。

最常见的模式是：

• 创建一个继承自 Interactable
• 调用 this.set_listener(this) 在 ao_start
• 实现 can_use 和 on_interact 在你的类中

如果你在代码中添加了一个新的 interactable 类，仍然需要在编辑器中将该组件添加到实体上（或者生成一个实体并在运行时添加该组件）。

垃圾示例

// 捡起垃圾可获得金币 :D
Trash :: class : Interactable {
    coins: s64 @ao_serialize;
    used: bool;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("捡起垃圾");
        this.set_hold_text("正在捡起...");
        required_hold_time = 0.25;
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        if used return false;
        return true;
    }

    on_interact :: method(player: Player) {
        used = true;
        Economy.deposit_currency(player, "Coins", coins);
        entity.destroy();
    }
}

放大示例

一个会“放大”实体的交互物（仅一次）：

Grow_Button :: class : Interactable {
    scale_multiplier: float @ao_serialize;
    used: bool;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("放大");
        radius = 1.25;
        required_hold_time = 0;
    }

    can_use :: method(player: Player) -> bool {
        return !used;
    }

    on_interact :: method(player: Player) {
        used = true;
        new_scale := entity.local_scale * scale_multiplier;
        entity.set_local_scale(new_scale);
        this.set_text("已使用过");
    }
}

购买提示示例

一个会提示购买商品的交互物：

Buy_Admin_Pass :: class : Interactable {
    product_id: string @ao_serialize;

    ao_start :: method() {
        this.set_listener(this);
        this.set_text("购买管理员通行证");
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        // 示例条件：如果已拥有则隐藏（游戏通行证）
        return !Purchasing.owns_product(player, product_id);
    }

    on_interact :: method(player: Player) {
        Purchasing.prompt_purchase(player, product_id);
    }
}

API 参考

Interactable :: class : Component {
    // 提示文本（轻触交互）
    get_text :: method() -> string;
    set_text :: method(text: string);

    // 按住时的提示文本（用于按住交互）
    get_hold_text :: method() -> string;
    set_hold_text :: method(text: string);

    get_subtitle :: method() -> string;
    set_subtitle :: method(text: string);

    // 绑定一个实现以下接口的监听对象：
    // - can_use(player: Player) -> bool
    // - on_interact(player: Player)
    // - on_holding(player: Player) [可选]
    set_listener :: method(new_listener: Component);

    // 常用字段（在编辑器或代码中设置）
    offset: v2;
    prompt_offset: v2;
    radius: float;
    required_hold_time: float;
    priority: s64;
    subtitle_color: v4;
}

可选的玩家钩子（全局规则）

你也可以在你的 Player 类中实现这些，以强制执行全局规则（例如：在重生前不能使用交互物）：

Player :: class : Player_Base {
    ao_can_use_interactable :: method(interactable: Interactable) -> bool {
        return true;
    }

    ao_on_interactable_used :: method(interactable: Interactable) {
    }

    ao_on_holding_interactable :: method(interactable: Interactable) {
    }
}