构建一个基础游戏

为了帮助你入门，本指南将带你制作一个苹果收集游戏！

苹果收集

这个示例游戏会略过一些在其他指南中有深入讲解的细节。如果你需要任何帮助，请查看左侧边栏，或使用顶部的搜索功能获取更多信息！

构建地图

我们将先创建一个基础世界，里面有一个可走动的小岛，以及一个稍后可以收集的苹果！

1. 在……中搜索 Apple 和 Island 资源目录 并将它们拖到你游戏的场景视图中。

1. 那个岛太小了！在……中 检查器 将 缩放 设置为 10x10，让它变大

1. 现在这个岛的大小合适了，但苹果在岛后面！将岛屿的 图层 设置为 -10，把它推到其他所有东西后面。

添加脚本

在你游戏项目的 scripts 目录中，创建一个名为 pickup_apple.csl 的新文件，并在文本编辑器中打开它，或者使用一个 基于 AI 的 IDE.

粘贴下面的示例脚本并保存文件：

// 这会创建一个让苹果可交互的组件，
// 我们会在教程的下一步把它添加到 Apple 上。 
Pickup_Apple :: class : Interactable {
    is_picked_up: bool;

    ao_start :: method() {
        this->set_listener(this);
        this->set_text("捡起");
    }

    can_use :: method(player: Player) -> bool {
        if is_picked_up return false;
        return true;
    }

    on_interact :: method(player: Player) {
        if is_picked_up return;
        is_picked_up = true;

        // 开始弹出效果
        effect := new(Apple_Pop_Effect);
        entity->set_active_effect(effect);
    }
}

// 一个你吃掉它时的酷动画 :D 
Apple_Pop_Effect :: class : Effect_Base {
    sprite: Sprite_Renderer;
    start_scale: v2;
    start_pos: v2;

    effect_start :: method() {
        sprite = entity->get_component(Sprite_Renderer);
        start_scale = entity.local_scale;
        start_pos = entity.local_position;
        set_duration(0.4);
    }

    effect_update :: method(dt: float) {
        t := get_elapsed_time() / 0.4;

        // 先放大，然后迅速缩小到消失
        scale_curve: float;
        if t < 0.3 {
            // 快速弹出（缩放到 1.3 倍）
            scale_curve = lerp(1.0, 1.3, Ease.out_back(t / 0.3));
        } else {
            // 缩小到消失
            scale_curve = lerp(1.3, 0.0, Ease.in_back((t - 0.3) / 0.7));
        }

        entity->set_local_scale(start_scale * scale_curve);

        // 略微向上浮动
        rise := Ease.out_quad(t) * 0.5;
        entity->set_local_position({start_pos.x, start_pos.y + rise});

        // 在接近结尾时淡出
        if sprite != null {
            alpha := 1.0 - Ease.in_quad(max(0.0, (t - 0.5) / 0.5));
            sprite.color.w = alpha;
        }
    }

    effect_end :: method(interrupt: bool) {
        entity->destroy();
    }
}

警告： 在文本编辑器中保存你的组件后，你需要按 Ctrl + Shift + R来刷新引擎。这是一个临时要求，很快就会支持热加载！

添加 Apple 组件

现在你已经创建了苹果脚本，我们需要把它应用到场景中的苹果上。为此，我们将通过检查器添加新的 Pickup_Apple 脚本中的组件。

1. 在场景中选中你的 Apple

2. 点击检查器中的“Add Component”按钮。

3. 搜索“Pickup_Apple”组件并点击它，将其添加到苹果上

现在你会看到该组件已经添加到苹果上了！你可以通过在检查器中更改数值，从 Apple 调整一些字段：

运行你的游戏

准备好后，点击有趣的绿色三角形并试试你的游戏！

下一步

在接下来的章节中，你将学习如何用多个玩家进行游戏测试，创建自己的脚本，以及构建你梦想中的世界。

这里有一些可以尝试的挑战：

• 做很多苹果让玩家吃

• 被吃掉时播放音效

• 高级： 尝试编写一个脚本，在苹果被吃掉后重新生成更多苹果

--

附注：如果你的岛屿分辨率很低/像素化，点击“Assets”部分中岛屿的 png 资源，将 Resample Multiplier 设置为 1，然后点击 Apply