Interactivos

El Componente Interactable

Agregar un componente Interactable a una entidad mostrará automáticamente la interfaz cuando los jugadores estén dentro del Radio que especifiques.

Para responder a que el jugador presione el interactuable, necesitarás escribir código CSL.

El patrón más común es:

• Crea una clase que herede de Interactable

• Llama this->set_listener(this) en ao_start

• Implementa can_use y on_interact en tu clase

Si agregas una nueva clase interactuable en el código, todavía necesitas añadir ese componente a una entidad en el editor (o generar una entidad y añadir el componente en tiempo de ejecución).

Ejemplo de Basura

// Consigue monedas por recoger la basura :D 
Trash :: class : Interactable {
    coins: s64 @ao_serialize;
    used: bool;

    ao_start :: method() {
        this->set_listener(this);
        this->set_text("Recoger basura");
        this->set_hold_text("Recogiendo...");
        required_hold_time = 0.25;
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        if used return false;
        return true;
    }

    on_interact :: method(player: Player) {
        used = true;
        Economy.deposit_currency(player, "Coins", coins);
        entity->destroy();
    }
}

Ejemplo de Crecimiento

Un interactuable que “hace crecer” una entidad (una vez):

Grow_Button :: class : Interactable {
    scale_multiplier: float @ao_serialize;
    used: bool;

    ao_start :: method() {
        this->set_listener(this);
        this->set_text("Crecer");
        radius = 1.25;
        required_hold_time = 0;
    }

    can_use :: method(player: Player) -> bool {
        return !used;
    }

    on_interact :: method(player: Player) {
        used = true;
        new_scale := entity.local_scale * scale_multiplier;
        entity->set_local_scale(new_scale);
        this->set_text("Ya usado");
    }
}

Ejemplo de Compra con Aviso

Un interactuable que solicita la compra de un producto:

Buy_Admin_Pass :: class : Interactable {
    product_id: string @ao_serialize;

    ao_start :: method() {
        this->set_listener(this);
        this->set_text("Comprar Pase de Administrador");
        radius = 1.25;
    }

    can_use :: method(player: Player) -> bool {
        // Ejemplo de puerta: ocultar si ya es propiedad (pase de juego)
        return !Purchasing.owns_product(player, product_id);
    }

    on_interact :: method(player: Player) {
        Purchasing.prompt_purchase(player, product_id);
    }
}

Referencia de la API

Interactable :: class : Component {
    // Texto del aviso (interacción por toque)
    get_text :: method() -> string;
    set_text :: method(text: string);

    // Texto del aviso mientras se mantiene (para mantener-para-interactuar)
    get_hold_text :: method() -> string;
    set_hold_text :: method(text: string);

    // Conecta un objeto listener que implemente:
    // - can_use(player: Player) -> bool
    // - on_interact(player: Player)
    // - on_holding(player: Player) [opcional]
    set_listener :: method(new_listener: Component);

    // Campos comunes (configurar en el editor o en el código)
    offset: v2;
    prompt_offset: v2;
    radius: float;
    required_hold_time: float;
    priority: s64;
}

Hooks opcionales para el jugador (reglas globales)

También puedes implementar estos en tu Player clase para hacer cumplir reglas a nivel de juego (p. ej., no poder usar interactuables antes de reaparecer):

Player :: class : Player_Base {
    ao_can_use_interactable :: method(interactable: Interactable) -> bool {
        return true;
    }

    ao_on_interactable_used :: method(interactable: Interactable) {
    }

    ao_on_holding_interactable :: method(interactable: Interactable) {
    }
}